* SPSS syntax to generate:
* CFSR Item V) Maltreatment Fatalities, Unique Child Victims.
* Syntax applies to NCANDS Child File V4.0. 
* NOTE: CFSR Item V holds a count of unique fatalities generated by this syntax PLUS the number
* of fatalities reported in Agency file.
************************************************************************************.
****** Lines beginning with '*' are comments and are not executed by SPSS.     *****.
****** Name of State Master File must be entered in highlighted section below. *****.
************************************************************************************.
* Field CHID (Child ID) used to identify unique victims.
* Fields MAL1LEV MAL2LEV MAL3LEV MAL4LEV and MALDEATH are used to identify maltreatment victims.
* Non-victims are removed from the analysis.
* Field MALDEATH used to identify victims whose maltreatment was fatal.

**********************************************************************************.
********** Enter name of the State Master File in following command line *********.
get file = 'ENTER STATE FILE NAME HERE' 
        /keep = chid mal1lev mal2lev mal3lev mal4lev maldeath.

* Create flag variable FLVICTIM to identify maltreatment victims.
* If any of the maltreatment dispositions (MALLEV)are 1=sub or 2=ind, or 3=alt-resp victim
* The child was a victim.
* If the child died as result of the maltreatment MALDEATH=1, the child was a victim.
compute flvictim = 0 .
if (mal1lev le 3) flvictim = 1.
if (mal2lev le 3) flvictim = 1.
if (mal3lev le 3) flvictim = 1.
if (mal4lev le 3) flvictim = 1.
if (maldeath eq 1) flvictim = 1.

* Analysis does not include non-victims and they are removed from the file.
select if (flvictim eq 1) .

* Set values for MALDEATH so that victims are either '1'='Fatal Victim' or '0'='Not Fatal'.
recode maldeath (1=1) (else = 0) .
var labels maldeath "Maltreatment Contributed to Child's Death".
val labels maldeath 1 'Yes' 0 'No' . 

* Active file currently holds records for duplicate victims.
* File of unique victims is created by selecting one record per victim.
* If any records for the victim indicate that a fatality occurred, then
*     this should be reflected in the single record.
* SORT command groups records in order by Child ID and then by MALDEATH in descending order.
* The inclusion of MALDEATH in the sort command ensures that the first record will 
* hold MALDEATH = 1 if any record for the child holds MALDEATH = 1. 
sort cases by chid (a) maldeath (d) .
* Select only the first record for each victim.
* Syntax means, 'select if current record is not the same child as identified in 
*   previous record (i.e., a new child)'.
select if (chid ne lag(chid)) .

* Active file currently holds records for unique victims.
* No additional case selection is required.
* Counts displayed are counts of unique victims by fatal maltreatment. 
freq maldeath.